<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">
require 5;
package Pod::Simple::RTF;

#sub DEBUG () {4};
#sub Pod::Simple::DEBUG () {4};
#sub Pod::Simple::PullParser::DEBUG () {4};

use strict;
use vars qw($VERSION @ISA %Escape $WRAP %Tagmap);
$VERSION = '3.35';
use Pod::Simple::PullParser ();
BEGIN {@ISA = ('Pod::Simple::PullParser')}

use Carp ();
BEGIN { *DEBUG = \&amp;Pod::Simple::DEBUG unless defined &amp;DEBUG }

$WRAP = 1 unless defined $WRAP;

# These are broken for early Perls on EBCDIC; they could be fixed to work
# better there, but not worth it.  These are part of a larger [...] class, so
# are just the strings to substitute into it, as opposed to compiled patterns.
my $cntrl = '[:cntrl:]';
$cntrl = '\x00-\x1F\x7F' unless eval "qr/[$cntrl]/";

my $not_ascii = '[:^ascii:]';
$not_ascii = '\x80-\xFF' unless eval "qr/[$not_ascii]/";


#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

sub _openclose {
 return map {;
   m/^([-A-Za-z]+)=(\w[^\=]*)$/s or die "what's &lt;$_&gt;?";
   ( $1,  "{\\$2\n",   "/$1",  "}" );
 } @_;
}

my @_to_accept;

%Tagmap = (
 # 'foo=bar' means ('foo' =&gt; '{\bar'."\n", '/foo' =&gt; '}')
 _openclose(
  'B=cs18\b',
  'I=cs16\i',
  'C=cs19\f1\lang1024\noproof',
  'F=cs17\i\lang1024\noproof',

  'VerbatimI=cs26\i',
  'VerbatimB=cs27\b',
  'VerbatimBI=cs28\b\i',

  map {; m/^([-a-z]+)/s &amp;&amp; push @_to_accept, $1; $_ }
   qw[
       underline=ul         smallcaps=scaps  shadow=shad
       superscript=super    subscript=sub    strikethrough=strike
       outline=outl         emboss=embo      engrave=impr   
       dotted-underline=uld          dash-underline=uldash
       dot-dash-underline=uldashd    dot-dot-dash-underline=uldashdd     
       double-underline=uldb         thick-underline=ulth
       word-underline=ulw            wave-underline=ulwave
   ]
   # But no double-strikethrough, because MSWord can't agree with the
   #  RTF spec on whether it's supposed to be \strikedl or \striked1 (!!!)
 ),

 # Bit of a hack here:
 'L=pod' =&gt; '{\cs22\i'."\n",
 'L=url' =&gt; '{\cs23\i'."\n",
 'L=man' =&gt; '{\cs24\i'."\n",
 '/L' =&gt; '}',

 'Data'  =&gt; "\n",
 '/Data' =&gt; "\n",

 'Verbatim'  =&gt; "\n{\\pard\\li#rtfindent##rtfkeep#\\plain\\s20\\sa180\\f1\\fs18\\lang1024\\noproof\n",
 '/Verbatim' =&gt; "\n\\par}\n",
 'VerbatimFormatted'  =&gt; "\n{\\pard\\li#rtfindent##rtfkeep#\\plain\\s20\\sa180\\f1\\fs18\\lang1024\\noproof\n",
 '/VerbatimFormatted' =&gt; "\n\\par}\n",
 'Para'    =&gt; "\n{\\pard\\li#rtfindent#\\sa180\n",
 '/Para'   =&gt; "\n\\par}\n",
 'head1'   =&gt; "\n{\\pard\\li#rtfindent#\\s31\\keepn\\sb90\\sa180\\f2\\fs#head1_halfpoint_size#\\ul{\n",
 '/head1'  =&gt; "\n}\\par}\n",
 'head2'   =&gt; "\n{\\pard\\li#rtfindent#\\s32\\keepn\\sb90\\sa180\\f2\\fs#head2_halfpoint_size#\\ul{\n",
 '/head2'  =&gt; "\n}\\par}\n",
 'head3'   =&gt; "\n{\\pard\\li#rtfindent#\\s33\\keepn\\sb90\\sa180\\f2\\fs#head3_halfpoint_size#\\ul{\n",
 '/head3'  =&gt; "\n}\\par}\n",
 'head4'   =&gt; "\n{\\pard\\li#rtfindent#\\s34\\keepn\\sb90\\sa180\\f2\\fs#head4_halfpoint_size#\\ul{\n",
 '/head4'  =&gt; "\n}\\par}\n",
   # wordpad borks on \tc\tcl1, or I'd put that in =head1 and =head2

 'item-bullet'  =&gt; "\n{\\pard\\li#rtfindent##rtfitemkeepn#\\sb60\\sa150\\fi-120\n",
 '/item-bullet' =&gt; "\n\\par}\n",
 'item-number'  =&gt; "\n{\\pard\\li#rtfindent##rtfitemkeepn#\\sb60\\sa150\\fi-120\n",
 '/item-number' =&gt; "\n\\par}\n",
 'item-text'    =&gt; "\n{\\pard\\li#rtfindent##rtfitemkeepn#\\sb60\\sa150\\fi-120\n",
 '/item-text'   =&gt; "\n\\par}\n",

 # we don't need any styles for over-* and /over-*
);


#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
sub new {
  my $new = shift-&gt;SUPER::new(@_);
  $new-&gt;nix_X_codes(1);
  $new-&gt;nbsp_for_S(1);
  $new-&gt;accept_targets( 'rtf', 'RTF' );

  $new-&gt;{'Tagmap'} = {%Tagmap};

  $new-&gt;accept_codes(@_to_accept);
  $new-&gt;accept_codes('VerbatimFormatted');
  DEBUG &gt; 2 and print STDERR "To accept: ", join(' ',@_to_accept), "\n";
  $new-&gt;doc_lang(
    (  $ENV{'RTFDEFLANG'} || '') =~ m/^(\d{1,10})$/s ? $1
    : ($ENV{'RTFDEFLANG'} || '') =~ m/^0?x([a-fA-F0-9]{1,10})$/s ? hex($1)
                                      # yes, tolerate hex!
    : ($ENV{'RTFDEFLANG'} || '') =~ m/^([a-fA-F0-9]{4})$/s ? hex($1)
                                      # yes, tolerate even more hex!
    : '1033'
  );

  $new-&gt;head1_halfpoint_size(32);
  $new-&gt;head2_halfpoint_size(28);
  $new-&gt;head3_halfpoint_size(25);
  $new-&gt;head4_halfpoint_size(22);
  $new-&gt;codeblock_halfpoint_size(18);
  $new-&gt;header_halfpoint_size(17);
  $new-&gt;normal_halfpoint_size(25);

  return $new;
}

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

__PACKAGE__-&gt;_accessorize(
 'doc_lang',
 'head1_halfpoint_size',
 'head2_halfpoint_size',
 'head3_halfpoint_size',
 'head4_halfpoint_size',
 'codeblock_halfpoint_size',
 'header_halfpoint_size',
 'normal_halfpoint_size',
 'no_proofing_exemptions',
);


#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
sub run {
  my $self = $_[0];
  return $self-&gt;do_middle if $self-&gt;bare_output;
  return
   $self-&gt;do_beginning &amp;&amp; $self-&gt;do_middle &amp;&amp; $self-&gt;do_end;
}


#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

sub do_middle {      # the main work
  my $self = $_[0];
  my $fh = $self-&gt;{'output_fh'};
  
  my($token, $type, $tagname, $scratch);
  my @stack;
  my @indent_stack;
  $self-&gt;{'rtfindent'} = 0 unless defined $self-&gt;{'rtfindent'};
  
  while($token = $self-&gt;get_token) {
  
    if( ($type = $token-&gt;type) eq 'text' ) {
      if( $self-&gt;{'rtfverbatim'} ) {
        DEBUG &gt; 1 and print STDERR "  $type " , $token-&gt;text, " in verbatim!\n";
        rtf_esc_codely($scratch = $token-&gt;text);
        print $fh $scratch;
        next;
      }

      DEBUG &gt; 1 and print STDERR "  $type " , $token-&gt;text, "\n";
      
      $scratch = $token-&gt;text;
      $scratch =~ tr/\t\cb\cc/ /d;
      
      $self-&gt;{'no_proofing_exemptions'} or $scratch =~
       s/(?:
           ^
           |
           (?&lt;=[\r\n\t "\[\&lt;\(])
         )   # start on whitespace, sequence-start, or quote
         ( # something looking like a Perl token:
          (?:
           [\$\@\:\&lt;\*\\_]\S+  # either starting with a sigil, etc.
          )
          |
          # or starting alpha, but containing anything strange:
          (?:
           [a-zA-Z'${not_ascii}]+[\$\@\:_&lt;&gt;\(\\\*]\S+
          )
         )
        /\cb$1\cc/xsg
      ;
      
      rtf_esc($scratch);
      $scratch =~
         s/(
            [^\r\n]{65}        # Snare 65 characters from a line
            [^\r\n ]{0,50}     #  and finish any current word
           )
           (\ {1,10})(?![\r\n]) # capture some spaces not at line-end
          /$1$2\n/gx     # and put a NL before those spaces
        if $WRAP;
        # This may wrap at well past the 65th column, but not past the 120th.
      
      print $fh $scratch;

    } elsif( $type eq 'start' ) {
      DEBUG &gt; 1 and print STDERR "  +$type ",$token-&gt;tagname,
        " (", map("&lt;$_&gt; ", %{$token-&gt;attr_hash}), ")\n";

      if( ($tagname = $token-&gt;tagname) eq 'Verbatim'
          or $tagname eq 'VerbatimFormatted'
      ) {
        ++$self-&gt;{'rtfverbatim'};
        my $next = $self-&gt;get_token;
        next unless defined $next;
        my $line_count = 1;
        if($next-&gt;type eq 'text') {
          my $t = $next-&gt;text_r;
          while( $$t =~ m/$/mg ) {
            last if  ++$line_count  &gt; 15; # no point in counting further
          }
          DEBUG &gt; 3 and print STDERR "    verbatim line count: $line_count\n";
        }
        $self-&gt;unget_token($next);
        $self-&gt;{'rtfkeep'} = ($line_count &gt; 15) ? '' : '\keepn' ;     

      } elsif( $tagname =~ m/^item-/s ) {
        my @to_unget;
        my $text_count_here = 0;
        $self-&gt;{'rtfitemkeepn'} = '';
        # Some heuristics to stop item-*'s functioning as subheadings
        #  from getting split from the things they're subheadings for.
        #
        # It's not terribly pretty, but it really does make things pretty.
        #
        while(1) {
          push @to_unget, $self-&gt;get_token;
          pop(@to_unget), last unless defined $to_unget[-1];
           # Erroneously used to be "unshift" instead of pop!  Adds instead
           # of removes, and operates on the beginning instead of the end!
          
          if($to_unget[-1]-&gt;type eq 'text') {
            if( ($text_count_here += length ${$to_unget[-1]-&gt;text_r}) &gt; 150 ){
              DEBUG &gt; 1 and print STDERR "    item-* is too long to be keepn'd.\n";
              last;
            }
          } elsif (@to_unget &gt; 1 and
            $to_unget[-2]-&gt;type eq 'end' and
            $to_unget[-2]-&gt;tagname =~ m/^item-/s
          ) {
            # Bail out here, after setting rtfitemkeepn yea or nay.
            $self-&gt;{'rtfitemkeepn'} = '\keepn' if 
              $to_unget[-1]-&gt;type eq 'start' and
              $to_unget[-1]-&gt;tagname eq 'Para';

            DEBUG &gt; 1 and printf STDERR "    item-* before %s(%s) %s keepn'd.\n",
              $to_unget[-1]-&gt;type,
              $to_unget[-1]-&gt;can('tagname') ? $to_unget[-1]-&gt;tagname : '',
              $self-&gt;{'rtfitemkeepn'} ? "gets" : "doesn't get";
            last;
          } elsif (@to_unget &gt; 40) {
            DEBUG &gt; 1 and print STDERR "    item-* now has too many tokens (",
              scalar(@to_unget),
              (DEBUG &gt; 4) ? (q&lt;: &gt;, map($_-&gt;dump, @to_unget)) : (),
              ") to be keepn'd.\n";
            last; # give up
          }
          # else keep while'ing along
        }
        # Now put it aaaaall back...
        $self-&gt;unget_token(@to_unget);

      } elsif( $tagname =~ m/^over-/s ) {
        push @stack, $1;
        push @indent_stack,
         int($token-&gt;attr('indent') * 4 * $self-&gt;normal_halfpoint_size);
        DEBUG and print STDERR "Indenting over $indent_stack[-1] twips.\n";
        $self-&gt;{'rtfindent'} += $indent_stack[-1];
        
      } elsif ($tagname eq 'L') {
        $tagname .= '=' . ($token-&gt;attr('type') || 'pod');
        
      } elsif ($tagname eq 'Data') {
        my $next = $self-&gt;get_token;
        next unless defined $next;
        unless( $next-&gt;type eq 'text' ) {
          $self-&gt;unget_token($next);
          next;
        }
        DEBUG and print STDERR "    raw text ", $next-&gt;text, "\n";
        printf $fh "\n" . $next-&gt;text . "\n";
        next;
      }

      defined($scratch = $self-&gt;{'Tagmap'}{$tagname}) or next;
      $scratch =~ s/\#([^\#]+)\#/${$self}{$1}/g; # interpolate
      print $fh $scratch;
      
      if ($tagname eq 'item-number') {
        print $fh $token-&gt;attr('number'), ". \n";
      } elsif ($tagname eq 'item-bullet') {
        print $fh "\\'", ord("_"), "\n";
        #for funky testing: print $fh '', rtf_esc("\x{4E4B}\x{9053}");
      }

    } elsif( $type eq 'end' ) {
      DEBUG &gt; 1 and print STDERR "  -$type ",$token-&gt;tagname,"\n";
      if( ($tagname = $token-&gt;tagname) =~ m/^over-/s ) {
        DEBUG and print STDERR "Indenting back $indent_stack[-1] twips.\n";
        $self-&gt;{'rtfindent'} -= pop @indent_stack;
        pop @stack;
      } elsif( $tagname eq 'Verbatim' or $tagname eq 'VerbatimFormatted') {
        --$self-&gt;{'rtfverbatim'};
      }
      defined($scratch = $self-&gt;{'Tagmap'}{"/$tagname"}) or next;
      $scratch =~ s/\#([^\#]+)\#/${$self}{$1}/g; # interpolate
      print $fh $scratch;
    }
  }
  return 1;
}

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
sub do_beginning {
  my $self = $_[0];
  my $fh = $self-&gt;{'output_fh'};
  return print $fh join '',
    $self-&gt;doc_init,
    $self-&gt;font_table,
    $self-&gt;stylesheet,
    $self-&gt;color_table,
    $self-&gt;doc_info,
    $self-&gt;doc_start,
    "\n"
  ;
}

sub do_end {
  my $self = $_[0];
  my $fh = $self-&gt;{'output_fh'};
  return print $fh '}'; # that should do it
}

###########################################################################

sub stylesheet {
  return sprintf &lt;&lt;'END',
{\stylesheet
{\snext0 Normal;}
{\*\cs10 \additive Default Paragraph Font;}
{\*\cs16 \additive \i \sbasedon10 pod-I;}
{\*\cs17 \additive \i\lang1024\noproof \sbasedon10 pod-F;}
{\*\cs18 \additive \b \sbasedon10 pod-B;}
{\*\cs19 \additive \f1\lang1024\noproof\sbasedon10 pod-C;}
{\s20\ql \li0\ri0\sa180\widctlpar\f1\fs%s\lang1024\noproof\sbasedon0 \snext0 pod-codeblock;}
{\*\cs21 \additive \lang1024\noproof \sbasedon10 pod-computerese;}
{\*\cs22 \additive \i\lang1024\noproof\sbasedon10 pod-L-pod;}
{\*\cs23 \additive \i\lang1024\noproof\sbasedon10 pod-L-url;}
{\*\cs24 \additive \i\lang1024\noproof\sbasedon10 pod-L-man;}

{\*\cs25 \additive \f1\lang1024\noproof\sbasedon0 pod-codelbock-plain;}
{\*\cs26 \additive \f1\lang1024\noproof\sbasedon25 pod-codelbock-ital;}
{\*\cs27 \additive \f1\lang1024\noproof\sbasedon25 pod-codelbock-bold;}
{\*\cs28 \additive \f1\lang1024\noproof\sbasedon25 pod-codelbock-bold-ital;}

{\s31\ql \keepn\sb90\sa180\f2\fs%s\ul\sbasedon0 \snext0 pod-head1;}
{\s32\ql \keepn\sb90\sa180\f2\fs%s\ul\sbasedon0 \snext0 pod-head2;}
{\s33\ql \keepn\sb90\sa180\f2\fs%s\ul\sbasedon0 \snext0 pod-head3;}
{\s34\ql \keepn\sb90\sa180\f2\fs%s\ul\sbasedon0 \snext0 pod-head4;}
}

END

   $_[0]-&gt;codeblock_halfpoint_size(),
   $_[0]-&gt;head1_halfpoint_size(),
   $_[0]-&gt;head2_halfpoint_size(),
   $_[0]-&gt;head3_halfpoint_size(),
   $_[0]-&gt;head4_halfpoint_size(),
  ;
}

###########################################################################
# Override these as necessary for further customization

sub font_table {
  return &lt;&lt;'END';  # text font, code font, heading font
{\fonttbl
{\f0\froman Times New Roman;}
{\f1\fmodern Courier New;}
{\f2\fswiss Arial;}
}

END
}

sub doc_init {
   return &lt;&lt;'END';
{\rtf1\ansi\deff0

END
}

sub color_table {
   return &lt;&lt;'END';
{\colortbl;\red255\green0\blue0;\red0\green0\blue255;}
END
}


sub doc_info {
   my $self = $_[0];

   my $class = ref($self) || $self;

   my $tag = __PACKAGE__ . ' ' . $VERSION;
   
   unless($class eq __PACKAGE__) {
     $tag = " ($tag)";
     $tag = " v" . $self-&gt;VERSION . $tag   if   defined $self-&gt;VERSION;
     $tag = $class . $tag;
   }

   return sprintf &lt;&lt;'END',
{\info{\doccomm
%s
 using %s v%s
 under Perl v%s at %s GMT}
{\author [see doc]}{\company [see doc]}{\operator [see doc]}
}

END

  # None of the following things should need escaping, I dare say!
    $tag, 
    $ISA[0], $ISA[0]-&gt;VERSION(),
    $], scalar(gmtime),
  ;
}

sub doc_start {
  my $self = $_[0];
  my $title = $self-&gt;get_short_title();
  DEBUG and print STDERR "Short Title: &lt;$title&gt;\n";
  $title .= ' ' if length $title;
  
  $title =~ s/ *$/ /s;
  $title =~ s/^ //s;
  $title =~ s/ $/, /s;
   # make sure it ends in a comma and a space, unless it's 0-length

  my $is_obviously_module_name;
  $is_obviously_module_name = 1
   if $title =~ m/^\S+$/s and $title =~ m/::/s;
    # catches the most common case, at least

  DEBUG and print STDERR "Title0: &lt;$title&gt;\n";
  $title = rtf_esc($title);
  DEBUG and print STDERR "Title1: &lt;$title&gt;\n";
  $title = '\lang1024\noproof ' . $title
   if $is_obviously_module_name;

  return sprintf &lt;&lt;'END', 
\deflang%s\plain\lang%s\widowctrl
{\header\pard\qr\plain\f2\fs%s
%s
p.\chpgn\par}
\fs%s

END
    ($self-&gt;doc_lang) x 2,
    $self-&gt;header_halfpoint_size,
    $title,
    $self-&gt;normal_halfpoint_size,
  ;
}

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
#-------------------------------------------------------------------------

use integer;
sub rtf_esc {
  my $x; # scratch
  if(!defined wantarray) { # void context: alter in-place!
    for(@_) {
      s/([F${cntrl}\-\\\{\}${not_ascii}])/$Escape{$1}/g;  # ESCAPER
      s/([^\x00-\xFF])/'\\uc1\\u'.((ord($1)&lt;32768)?ord($1):(ord($1)-65536)).'?'/eg;
    }
    return;
  } elsif(wantarray) {  # return an array
    return map {; ($x = $_) =~
      s/([F${cntrl}\-\\\{\}${not_ascii}])/$Escape{$1}/g;  # ESCAPER
      $x =~ s/([^\x00-\xFF])/'\\uc1\\u'.((ord($1)&lt;32768)?ord($1):(ord($1)-65536)).'?'/eg;
      $x;
    } @_;
  } else { # return a single scalar
    ($x = ((@_ == 1) ? $_[0] : join '', @_)
    ) =~ s/([F${cntrl}\-\\\{\}${not_ascii}])/$Escape{$1}/g;  # ESCAPER
             # Escape \, {, }, -, control chars, and 7f-ff.
    $x =~ s/([^\x00-\xFF])/'\\uc1\\u'.((ord($1)&lt;32768)?ord($1):(ord($1)-65536)).'?'/eg;
    return $x;
  }
}

sub rtf_esc_codely {
  # Doesn't change "-" to hard-hyphen, nor apply computerese style-smarts.
  # We don't want to change the "-" to hard-hyphen, because we want to
  #  be able to paste this into a file and run it without there being
  #  dire screaming about the mysterious hard-hyphen character (which
  #  looks just like a normal dash character).
  
  my $x; # scratch
  if(!defined wantarray) { # void context: alter in-place!
    for(@_) {
      s/([F${cntrl}\\\{\}${not_ascii}])/$Escape{$1}/g;  # ESCAPER
      s/([^\x00-\xFF])/'\\uc1\\u'.((ord($1)&lt;32768)?ord($1):(ord($1)-65536)).'?'/eg;
    }
    return;
  } elsif(wantarray) {  # return an array
    return map {; ($x = $_) =~
      s/([F${cntrl}\\\{\}${not_ascii}])/$Escape{$1}/g;  # ESCAPER
      $x =~ s/([^\x00-\xFF])/'\\uc1\\u'.((ord($1)&lt;32768)?ord($1):(ord($1)-65536)).'?'/eg;
      $x;
    } @_;
  } else { # return a single scalar
    ($x = ((@_ == 1) ? $_[0] : join '', @_)
    ) =~ s/([F${cntrl}\\\{\}${not_ascii}])/$Escape{$1}/g;  # ESCAPER
             # Escape \, {, }, -, control chars, and 7f-ff.
    $x =~ s/([^\x00-\xFF])/'\\uc1\\u'.((ord($1)&lt;32768)?ord($1):(ord($1)-65536)).'?'/eg;
    return $x;
  }
}

%Escape = (
  (($] lt 5.007_003) # Broken for non-ASCII on early Perls
   ? (map( (chr($_),chr($_)), # things not apparently needing escaping
       0x20 .. 0x7E ),
      map( (chr($_),sprintf("\\'%02x", $_)), # apparently escapeworthy things
       0x00 .. 0x1F, 0x5c, 0x7b, 0x7d, 0x7f .. 0xFF, 0x46))
   : (map( (chr(utf8::unicode_to_native($_)),chr(utf8::unicode_to_native($_))),
       0x20 .. 0x7E ),
      map( (chr($_),sprintf("\\'%02x", utf8::unicode_to_native($_))),
       0x00 .. 0x1F, 0x5c, 0x7b, 0x7d, 0x7f .. 0xFF, 0x46))),

  # We get to escape out 'F' so that we can send RTF files thru the mail
  # without the slightest worry that paragraphs beginning with "From"
  # will get munged.

  # And some refinements:
  "\r"  =&gt; "\n",
  "\cj"  =&gt; "\n",
  "\n"   =&gt; "\n\\line ",

  "\t"   =&gt; "\\tab ",     # Tabs (altho theoretically raw \t's are okay)
  "\f"   =&gt; "\n\\page\n", # Formfeed
  "-"    =&gt; "\\_",        # Turn plaintext '-' into a non-breaking hyphen
  $Pod::Simple::nbsp =&gt; "\\~",        # Latin-1 non-breaking space
  $Pod::Simple::shy =&gt; "\\-",        # Latin-1 soft (optional) hyphen

  # CRAZY HACKS:
  "\n" =&gt; "\\line\n",
  "\r" =&gt; "\n",
  "\cb" =&gt; "{\n\\cs21\\lang1024\\noproof ",  # \\cf1
  "\cc" =&gt; "}",
);
1;

__END__

=head1 NAME

Pod::Simple::RTF -- format Pod as RTF

=head1 SYNOPSIS

  perl -MPod::Simple::RTF -e \
   "exit Pod::Simple::RTF-&gt;filter(shift)-&gt;any_errata_seen" \
   thingy.pod &gt; thingy.rtf

=head1 DESCRIPTION

This class is a formatter that takes Pod and renders it as RTF, good for
viewing/printing in MSWord, WordPad/write.exe, TextEdit, etc.

This is a subclass of L&lt;Pod::Simple&gt; and inherits all its methods.

=head1 FORMAT CONTROL ATTRIBUTES

You can set these attributes on the parser object before you
call C&lt;parse_file&gt; (or a similar method) on it:

=over

=item $parser-&gt;head1_halfpoint_size( I&lt;halfpoint_integer&gt; );

=item $parser-&gt;head2_halfpoint_size( I&lt;halfpoint_integer&gt; );

=item $parser-&gt;head3_halfpoint_size( I&lt;halfpoint_integer&gt; );

=item $parser-&gt;head4_halfpoint_size( I&lt;halfpoint_integer&gt; );

These methods set the size (in half-points, like 52 for 26-point)
that these heading levels will appear as.

=item $parser-&gt;codeblock_halfpoint_size( I&lt;halfpoint_integer&gt; );

This method sets the size (in half-points, like 21 for 10.5-point)
that codeblocks ("verbatim sections") will appear as.

=item $parser-&gt;header_halfpoint_size( I&lt;halfpoint_integer&gt; );

This method sets the size (in half-points, like 15 for 7.5-point)
that the header on each page will appear in.  The header
is usually just "I&lt;modulename&gt; p. I&lt;pagenumber&gt;".

=item $parser-&gt;normal_halfpoint_size( I&lt;halfpoint_integer&gt; );

This method sets the size (in half-points, like 26 for 13-point)
that normal paragraphic text will appear in.

=item $parser-&gt;no_proofing_exemptions( I&lt;true_or_false&gt; );

Set this value to true if you don't want the formatter to try
putting a hidden code on all Perl symbols (as best as it can
notice them) that labels them as being not in English, and
so not worth spellchecking.

=item $parser-&gt;doc_lang( I&lt;microsoft_decimal_language_code&gt; )

This sets the language code to tag this document as being in. By
default, it is currently the value of the environment variable
C&lt;RTFDEFLANG&gt;, or if that's not set, then the value
1033 (for US English).

Setting this appropriately is useful if you want to use the RTF
to spellcheck, and/or if you want it to hyphenate right.

Here are some notable values:

  1033  US English
  2057  UK English
  3081  Australia English
  4105  Canada English
  1034  Spain Spanish
  2058  Mexico Spanish
  1031  Germany German
  1036  France French
  3084  Canada French
  1035  Finnish
  1044  Norwegian (Bokmal)
  2068  Norwegian (Nynorsk)

=back

If you are particularly interested in customizing this module's output
even more, see the source and/or write to me.

=head1 SEE ALSO

L&lt;Pod::Simple&gt;, L&lt;RTF::Writer&gt;, L&lt;RTF::Cookbook&gt;, L&lt;RTF::Document&gt;,
L&lt;RTF::Generator&gt;

=head1 SUPPORT

Questions or discussion about POD and Pod::Simple should be sent to the
pod-people@perl.org mail list. Send an empty email to
pod-people-subscribe@perl.org to subscribe.

This module is managed in an open GitHub repository,
L&lt;https://github.com/perl-pod/pod-simple/&gt;. Feel free to fork and contribute, or
to clone L&lt;git://github.com/perl-pod/pod-simple.git&gt; and send patches!

Patches against Pod::Simple are welcome. Please send bug reports to
&lt;bug-pod-simple@rt.cpan.org&gt;.

=head1 COPYRIGHT AND DISCLAIMERS

Copyright (c) 2002 Sean M. Burke.

This library is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.

This program is distributed in the hope that it will be useful, but
without any warranty; without even the implied warranty of
merchantability or fitness for a particular purpose.

=head1 AUTHOR

Pod::Simple was created by Sean M. Burke &lt;sburke@cpan.org&gt;.
But don't bother him, he's retired.

Pod::Simple is maintained by:

=over

=item * Allison Randal C&lt;allison@perl.org&gt;

=item * Hans Dieter Pearcey C&lt;hdp@cpan.org&gt;

=item * David E. Wheeler C&lt;dwheeler@cpan.org&gt;

=back

=cut
</pre></body></html>